Thursday, September 1, 2022

[SOLVED] How can I initialize an instance with cloud-init on Terraform

Issue

I am trying to initialize AWS instances using cloud-init, I test with terraform code:

variable "hostname"    {}
variable "domain_name" {}


variable "filename" {
  default = "cloud-config.cfg"
}

data "template_file" "test" {
  template = <<EOF
#cloud-config
hostname: $${hostname}
fqdn: $${fqdn}
mounts:
  - [ ephemeral, null ]
output:
  all: '| tee -a /var/log/cloud-init-output.log'
EOF

  vars {
    hostname = "${var.hostname}"
    fqdn     = "${format("%s.%s", var.hostname, var.domain_name)}"
  }
}

data "template_cloudinit_config" "test" {
  gzip          = false
  base64_encode = false

  part {
    filename     = "${var.filename}"
    content_type = "text/cloud-config"
    content      = "${data.template_file.test.rendered}"
  }
}


resource "aws_instance" "bootstrap2" {
    ami = "${var.aws_centos_ami}"
    availability_zone = "eu-west-1b"
    instance_type = "t2.micro"
    key_name = "${var.aws_key_name}"
    security_groups = ["${aws_security_group.bastion.id}"]
    associate_public_ip_address = true
    private_ip = "10.0.0.12"
    source_dest_check = false
    subnet_id = "${aws_subnet.eu-west-1b-public.id}"
    triggers {
      template = "${data.template_file.test.rendered}"
    }

    tags {
            Name = "bootstrap2"
        }
}

But it is failing the triggers inside the "bootstrap" resource. So how can I aprovisione this instance with the cloud-config I defined up?


Solution

triggers is not a valid argument for an aws_instance resource. The usual way to pass configuration to cloud-init is via the user_data argument, like this:

resource "aws_instance" "bootstrap2" {
  ami = "${var.aws_centos_ami}"
  availability_zone = "eu-west-1b"
  instance_type = "t2.micro"
  key_name = "${var.aws_key_name}"
  security_groups = ["${aws_security_group.bastion.id}"]
  associate_public_ip_address = true
  private_ip = "10.0.0.12"
  source_dest_check = false
  subnet_id = "${aws_subnet.eu-west-1b-public.id}"

  # Pass templated configuration to cloud-init
  user_data = "${data.template_file.test.rendered}"

  tags {
    Name = "bootstrap2"
  }
}


Answered By - Martin Atkins
Answer Checked By - Senaida (WPSolving Volunteer)
at